An IKEA Skådis Corner Bumper

Miscellany

An IKEA Skådis Corner Bumper

February 24, 2024

This week I had a couple IKEA Skådis pegboards delivered¹. Each of them arrived with the corners mildly scuffed.

An IKEA Skådis pegboard with the corner scuffed and the brown of the particleboard showing through a tear in the black finish.
The other board was slightly less bad, but still had a visible scuff in one corner.

I thought about trying to exchange them, but the damage was so minor. Also, I figured that there was a decent chance this is just the level of quality one gets from IKEA QA/shipping and I’d be likely to get boards with similar cosmetic issues after a time-consuming exchange process. So instead, I got out my calipers and in about an hour had a simple design for some corner bumpers. I wanted to produce something that was clean and discreet enough that it would look like it could have been sold with the product.

[Javascript required to view 3D model]

They printed cleanly on my Prusa MINI+ and I’m happy with the results. They cover up the existing damage and, while the need to protect the boards hung on the wall is limited, they will protect all the corners from future damage should I move them.

Seven L shaped corner bumpers standing vertically on a 3D printer print bed.

The corner of a pegboard, now with a corner bumper slotted over the corner.

I printed them in black so they’d blend in, but I’m considering printing some in a brightly colored filament to give my walls a shot of color.

An IKEA Skådis board mounted on a wall. There are boxes and trays mounted on the board and an adjustable wrench hangs from a hook. On each corner of the board is a black bumper.

The model is available on Printables – and in OpenSCAD code²:

include <BOSL2/std.scad>
include <BOSL2/rounding.scad>

corner_radius = 10;
wall_thickness = 1.5;
floor_thickness = 10;
straight_edge_length = 20;
board_thickness = 5;

outer_radius = corner_radius + wall_thickness;
floor_inner_radius = outer_radius - floor_thickness;

wall = union([
    ring(
        r1 = corner_radius,
        r2 = outer_radius,
        angle = 90,
        n = 50,
    ),
    back(
        corner_radius,
        left(
            straight_edge_length,
            square([straight_edge_length, wall_thickness])
        )
    ),
    fwd(
        straight_edge_length,
        right(
            corner_radius,
            square([wall_thickness, straight_edge_length])
        )
    ),
]);

floor = union([
    ring(
        r1 = floor_inner_radius,
        r2 = outer_radius,
        angle = 90,
        n = 50,
    ),
    fwd(
        straight_edge_length,
        right(
            floor_inner_radius,
            square([floor_thickness, straight_edge_length])
        )
    ),
    back(
        floor_inner_radius,
        left(
            straight_edge_length,
            square([straight_edge_length, floor_thickness])
        )
    )
]);

offset_sweep(floor, wall_thickness, bottom=os_chamfer(1))
position(TOP + BACK)
offset_sweep(wall, board_thickness, anchor = BOTTOM + BACK)
position(TOP + BACK)
offset_sweep(floor, wall_thickness, top=os_chamfer(1), anchor = BOTTOM + BACK);

Organizing my space is part of my Season of Tidiness, which involves buying some home organizing supplies. ↩︎
Requires BOSL2, which has become indispensable in my OpenSCAD design process. ↩︎